Home > 1b > | ノート > 1b-06 時間を表示する

1b-06 時間を表示する

Posted by: masa
2009年11月 9日 14:40
1b | ノート

現在の時間を表示する。

hour, minute, second 時、分、秒

コンソールに日時を表示する

void setup() {
  size(100, 100);
  frameRate(1); //フレームレートを1に設定（毎秒1回draw関数を実行）
}

void draw() {
  int s = second(); //秒
  int m = minute(); //分
  int h = hour(); //時
  println(h + ":" + m + ":" + s); //コンソールに日時を表示
}

コンソールに日時を表示する（分と秒は2ケタで表示）

void setup() {
  size(100, 100);
  frameRate(1);
}

void draw() {
  int s = second();
  int m = minute();
  int h = hour();
  String t = h + ":" + nf(m, 2) + ":" + nf(s, 2);
  println(t);
}

ウィンドウに日時を表示する

PFont font;

void setup() {
  size(100, 100);
  frameRate(1);
  font = loadFont("Monaco-18.vlw");
  textFont(font);
  textAlign(RIGHT);
}

void draw() {
  background(0);
  int s = second();
  int m = minute();
  int h = hour();
  String t = h + ":" + nf(m, 2) + ":" + nf(s, 2);
  //println(t);
  text (t, 93, 55);
}

時間を視覚化する

長方形の長さで、時計を表現する

19:45:06

void setup() {
  size(240, 240);
  frameRate(1);
}

void draw() {
  background(204);
  int s = second();
  int m = minute();
  int h = hour();
  //長方形の長さで時計を表現する
  rect(0, 0, h*10, height/3); 
  rect(0, height/3, m*4, height/3);
  rect(0, height*2/3, s*4, height/3);
}

三針時計をつくる

※針の描画を理解するには、三角関数の知識が必要。

void setup() {
  size(240, 240);
  frameRate(1);
  smooth();
}

void draw() {
  background(204);
  noStroke();
  ellipse (120, 120, 200, 200);
  int s = second();
  int m = minute();
  int h = hour();
  stroke(0);
  strokeWeight(4);
  line(120, 120 , 60*cos(h % 12 * TWO_PI / 12 - HALF_PI) + 120, 60*sin(h % 12 * TWO_PI / 12 - HALF_PI) +120); //時針の描画
  strokeWeight(2);
  line(120, 120 , 80*cos(m * TWO_PI / 60 - HALF_PI) + 120, 80*sin(m * TWO_PI / 60 - HALF_PI) +120); //分針の描画
  strokeWeight(1);
  line(120, 120 , 90*cos(s * TWO_PI / 60 - HALF_PI) + 120, 90*sin(s * TWO_PI / 60 - HALF_PI) +120); //秒針の描画
}